Sayfa hit sayisi verilerini xml olarak depolamak ve sayfada göstermek
Kod:
sayfaismi.asp
<html>
<head>
<title>sayfaismi.asp</title>
</head>
<body>
sayfanızın diğer kodları
<%
Dim sayfaismi
sayfaismi="sayfaismi"
%>
<!-- #include file="xmlhit.asp" -->
sayfanızın diğer kodları
</body>
</html>
sayfaismi ne dikkat !
1- her sayfa için ayrı bir isim veriyoruz.
2- sayfaismi verilirken türkçe karekter kullanmıyoruz.
xmlhit.asp
<%
Dim anaveri
Dim anaverikontrol
Dim alttag
Dim Nosu
Dim sayfaTag
Nosu = 1
' xml verimizi yukluyoruz
Set anaveri = server.CreateObject("Microsoft.XMLDOM")
anaveri.async = False
anaverikontrol = anaveri.load(server.MapPath("xmlhit.xml"))
' xml verimiz yoksa yeni xml dosyası olusturuyoruz
If anaverikontrol = False Then
anaveri.appendChild(anaveri.createProcessingInstruction("xml","version=""1.0"""))
' sayfahitleri adında anatag olusturuluyor
anaveri.appendChild(anaveri.createElement("sayfahitleri"))
' sayfaismi adında bir tag oluşturuyoruz
Set alttag = anaveri.createElement(sayfaismi)
' sayfaismi tagımızın icerigini 1 yapıyoruz
alttag.text = Nosu
anaveri.documentElement.appendChild(alttag.cloneNode(True))
' xml verimiz varsa
Else
' xml verilerimizdeki sayfaismi tagını yakalıyoruz
Set sayfaTag=anaveri.getElementsByTagName(sayfaismi)
' xml verilerimizde sayfaismi diye bir tag Yoksa
If sayfaTag.length = False Then
' sayfaismi adında bir tag oluşturuyoruz
Set alttag = anaveri.createElement(sayfaismi)
' sayfaismi tagımızın icerigini 1 yapıyoruz
alttag.text = Nosu
anaveri.documentElement.appendChild(alttag.cloneNode(True))
' xml verilerimizde sayfaismi diye bir tag Varsa
Else
' sayfaismi tag icerigini bir artırıp yeniden dolduruyoruz
Nosu=sayfaTag.item(0).text + 1
sayfaTag.item(0).text = Nosu
End If
End If
' xml verilerimizi kayıt ediyoruz
anaveri.save(server.MapPath("xmlhit.xml"))
Set alttag = Nothing
Set anaveri = Nothing
Set sayfaTag = Nothing
' sayfanızda hit sayısını sayfaya yazıyoruz
Response.Write Nosu
%>
Brinkster için Uyarı:
xmlhit.asp Dosyası db klasorunuz içinde bulunmalıdır.
İsterseniz bir XSL dosyası oluşturup
sayaçlarınız çalışmaya başlamasından itibaren oluşacak olan xmlhit.xml dosyanızdaki tüm verileri gözlemleyebilirsiniz.